AMDISConfig.cmake.in

# This configuration file is shipped with the FEM-Toolbox AMDiS.
# It simplifies the configure of different amdis-versions.
#
# We set the following variables:
#   AMDIS_INCLUDE_DIRS    all include directories (mtl, umfpack, parmetis, metis, ...)
#   AMDIS_LIBRARIES       the needed libraries
#   AMDiS_COMPILEFLAGS    some compile flags for amdis
#
# Use this package in the following way:
#
#   find_package(AMDiS REQUIRED [PARALLEL|SEQUENTIAL])
#   add_executable(yourTarget <yourSources>)
#   include_directories(${AMDIS_INCLUDE_DIRS})
#   compile_definitions(${AMDIS_COMPILEFLAGS})
#   target_link_libraries(yourTarget ${AMDIS_LIBRARIES})
#
# Or directly link against target AMDiS:
#
#   find_package(AMDiS REQUIRED [ [PARALLEL|SEQUENTIAL] ])
#   add_executable(yourTarget <yourSources>)
#   target_link_libraries(yourTarget AMDiS)
#
# The default component for this package is SEQUENTIAL DEBUG.
#

if (${CMAKE_VERSION} VERSION_LESS "3.2")
  message(FATAL_ERROR "The Configuration file was created for CMake version >= 3.2")
endif ()

list(APPEND CMAKE_MODULE_PATH ${AMDIS_DIR})

set(IS_AMDISCONFIG true)

set(AMDIS_USE_FILE ${AMDIS_DIR}/AMDISUse.cmake)

# Include macros
include(target_enable_cxx11)
include(target_enable_mtl4)
include(target_enable_boost)
include(target_enable_umfpack)
include(target_enable_petsc)
include(target_enable_zoltan)
include(target_enable_bddcml)
include(target_enable_hypre)
include(target_enable_png)

# enable components
# -----------------

if (AMDIS_FIND_REQUIRED_PARALLEL AND AMDIS_FIND_REQUIRED_SEQUENTIAL)
  message(WARNING "Choose either SEQUENTIAL or PARALLEL as component, not both! Falling back to the default SEQUENTIAL.")
  set(AMDIS_FIND_REQUIRED_PARALLEL OFF)
endif ()

set(AMDIS_CONFIGURATION "")

# parallel of sequential version
if (AMDIS_FIND_REQUIRED_PARALLEL)
  set(AMDIS_HAS_PARALLEL_DOMAIN ON)
  set(POSTFIX "-p")
  list(APPEND AMDIS_CONFIGURATION "PARALLEL")
else ()
  set(AMDIS_HAS_PARALLEL_DOMAIN OFF)
  set(POSTFIX "-s")
  list(APPEND AMDIS_CONFIGURATION "SEQUENTIAL")
endif ()

if (MSVC)
  add_definitions(-DNOMINMAX -D_CONSOLE -DSTRICT -D_SCL_SECURE_NO_WARNINGS -D_CRT_SECURE_NO_WARNINGS)
endif (MSVC)

if (NOT EXISTS ${AMDIS_DIR}/AMDIS${POSTFIX}.cmake)
  message(FATAL_ERROR "Configuration ${AMDIS_CONFIGURATION} can not be found in ${AMDIS_DIR}.")
endif ()

# include component configuration
include(AMDIS${POSTFIX})